为什么生成的xml只有<?xml version="1.0" encoding="GB2312"?>


<!--#include file="GetDB.inc"-->
<%
on error resume next
Dim SQL,RS

Set RS = Server.CreateObject("ADODB.RecordSet")
Set conn = server.createobject("ADODB.connection")
OpenDBConn conn

SQL = "SELECT * FROM basic"
RS.Open SQL,Conn,1,1
RS.MoveFirst

Dim xmldoc
Set xmldoc = server.CreateObject("Msxml2.DOMDocument.4.0")

Dim version
Set version = xmldoc.createProcessingInstruction("xml","version='1.0' encoding='GB2312'")
xmldoc.appendchild(version)

Dim root
Set root = xmldoc.CreateNode("root")
xmldoc.appendChild(root)

while (Not RS.EOF)
Set childNode = xmldoc.CreateNode("student")
For Each f in rs.Fields
  Set childnextNode = xmldoc.CreateNode(f.name)
  childnextNode.Text = f.Value
  childNode.appendChild(childnextNode)
Next
RS.MoveNext
root.appendChild childNode
wend

xmldoc.save(Server.Mappath("info.xml"))

%>
---------------------------------------------------------------

我好像没有看见连接数据库的语句
---------------------------------------------------------------

xml/soap里给你回答了。
这个主要是你对xmldom的操作方法是错误的。
建议你多看看xmldom的sdk

http://www.chinaok.net/examples/
有几个例子。

---------------------------------------------------------------

不可能...至少会存在一个root结点..
去掉这一句:on error resume next看看运行效果


---------------------------------------------------------------

是啊！
调试阶段on error resume next可是大忌啊！！！
---------------------------------------------------------------

是啊！
调试阶段on error resume next可是大忌啊！！！

---------------------------------------------------------------

取数据有错，XMLDOM操作没错。
如果XMLDOM操作有错，则不会有<?xml version="1.0" encoding="GB2312"?>

你把on error resume next注释掉，就可以看到那行有错了。


---------------------------------------------------------------

Dim SQL,RS

Set RS = Server.CreateObject("ADODB.RecordSet")

SQL = "SELECT showname FROM download"
RS.Open SQL,Connys,1,1
RS.MoveFirst

Dim xmldoc
Set xmldoc = server.CreateObject("Msxml2.DOMDocument.4.0")

Dim version
Set version = xmldoc.createProcessingInstruction("xml","version='1.0' encoding='GB2312'")
xmldoc.appendchild(version)

Dim root
Set root = xmldoc.CreateNode(1, "root","")
xmldoc.appendChild(root)

do while (Not RS.EOF)
Set childNode = xmldoc.CreateNode(1,"student","")
For Each f in rs.Fields
  Set childnextNode = xmldoc.CreateNode(1,f.name,"")
  childnextNode.Text = f.Value
  childNode.appendChild(childnextNode)
Next
RS.MoveNext
root.appendChild childNode
loop

xmldoc.save(Server.Mappath("info.xml"))

%>
改了一下，试过了，成功！

该文章在 2011/4/13 14:59:55 编辑过